975db80ef6
Pointers can be either uniform or varying, and behave correspondingly. e.g.: "uniform float * varying" is a varying pointer to uniform float data in memory, and "float * uniform" is a uniform pointer to varying data in memory. Like other types, pointers are varying by default. Pointer-based expressions, & and *, sizeof, ->, pointer arithmetic, and the array/pointer duality all bahave as in C. Array arguments to functions are converted to pointers, also like C. There is a built-in NULL for a null pointer value; conversion from compile-time constant 0 values to NULL still needs to be implemented. Other changes: - Syntax for references has been updated to be C++ style; a useful warning is now issued if the "reference" keyword is used. - It is now illegal to pass a varying lvalue as a reference parameter to a function; references are essentially uniform pointers. This case had previously been handled via special case call by value return code. That path has been removed, now that varying pointers are available to handle this use case (and much more). - Some stdlib routines have been updated to take pointers as arguments where appropriate (e.g. prefetch and the atomics). A number of others still need attention. - All of the examples have been updated - Many new tests TODO: documentation
101 lines
3.7 KiB
Plaintext
101 lines
3.7 KiB
Plaintext
/*
|
|
Copyright (c) 2010-2011, Intel Corporation
|
|
All rights reserved.
|
|
|
|
Redistribution and use in source and binary forms, with or without
|
|
modification, are permitted provided that the following conditions are
|
|
met:
|
|
|
|
* Redistributions of source code must retain the above copyright
|
|
notice, this list of conditions and the following disclaimer.
|
|
|
|
* Redistributions in binary form must reproduce the above copyright
|
|
notice, this list of conditions and the following disclaimer in the
|
|
documentation and/or other materials provided with the distribution.
|
|
|
|
* Neither the name of Intel Corporation nor the names of its
|
|
contributors may be used to endorse or promote products derived from
|
|
this software without specific prior written permission.
|
|
|
|
|
|
THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS
|
|
IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
|
|
TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A
|
|
PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER
|
|
OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
|
|
EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
|
|
PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
|
|
PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
|
|
LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
|
|
NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
|
|
SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
|
|
*/
|
|
|
|
static inline int
|
|
mandel(float c_re, float c_im, int count) {
|
|
float z_re = c_re, z_im = c_im;
|
|
int i;
|
|
for (i = 0; i < count; ++i) {
|
|
if (z_re * z_re + z_im * z_im > 4.)
|
|
break;
|
|
|
|
float new_re = z_re*z_re - z_im*z_im;
|
|
float new_im = 2.f * z_re * z_im;
|
|
z_re = c_re + new_re;
|
|
z_im = c_im + new_im;
|
|
}
|
|
|
|
return i;
|
|
}
|
|
|
|
|
|
/* Task to compute the Mandelbrot iterations for a span of scanlines from
|
|
[ystart,yend).
|
|
*/
|
|
task void
|
|
mandelbrot_scanlines(uniform int ybase, uniform int span,
|
|
uniform float x0, uniform float dx,
|
|
uniform float y0, uniform float dy,
|
|
uniform int width, uniform int maxIterations,
|
|
uniform int output[]) {
|
|
uniform int ystart = ybase + taskIndex * span;
|
|
uniform int yend = ystart + span;
|
|
|
|
for (uniform int j = ystart; j < yend; ++j) {
|
|
for (uniform int i = 0; i < width; i += programCount) {
|
|
float x = x0 + (programIndex + i) * dx;
|
|
float y = y0 + j * dy;
|
|
|
|
int index = j * width + i + programIndex;
|
|
output[index] = mandel(x, y, maxIterations);
|
|
}
|
|
}
|
|
}
|
|
|
|
|
|
task void
|
|
mandelbrot_chunk(uniform float x0, uniform float dx,
|
|
uniform float y0, uniform float dy,
|
|
uniform int width, uniform int height,
|
|
uniform int maxIterations, uniform int output[]) {
|
|
uniform int ystart = taskIndex * (height/taskCount);
|
|
uniform int yend = (taskIndex+1) * (height/taskCount);
|
|
uniform int span = 1;
|
|
|
|
launch[(yend-ystart)/span] < mandelbrot_scanlines(ystart, span, x0, dx, y0, dy,
|
|
width, maxIterations, output) >;
|
|
}
|
|
|
|
|
|
export void
|
|
mandelbrot_ispc(uniform float x0, uniform float y0,
|
|
uniform float x1, uniform float y1,
|
|
uniform int width, uniform int height,
|
|
uniform int maxIterations, uniform int output[]) {
|
|
uniform float dx = (x1 - x0) / width;
|
|
uniform float dy = (y1 - y0) / height;
|
|
|
|
launch[32] < mandelbrot_chunk(x0, dx, y0, dy, width, height,
|
|
maxIterations, output) >;
|
|
}
|