First commit of the radix sort example.

examples/sort/sort.ispc

@@ -0,0 +1,206 @@
+/*
+  Copyright (c) 2013, Durham University
+  All rights reserved.
+
+  Redistribution and use in source and binary forms, with or without
+  modification, are permitted provided that the following conditions are
+  met:
+
+    * Redistributions of source code must retain the above copyright
+      notice, this list of conditions and the following disclaimer.
+
+    * Redistributions in binary form must reproduce the above copyright
+      notice, this list of conditions and the following disclaimer in the
+      documentation and/or other materials provided with the distribution.
+
+    * Neither the name of Durham University nor the names of its
+      contributors may be used to endorse or promote products derived from
+      this software without specific prior written permission.
+
+
+   THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS
+   IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
+   TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A
+   PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER
+   OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
+   EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
+   PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
+   PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
+   LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
+   NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
+   SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.  
+*/
+
+task void histogram (uniform int span, uniform int n, uniform int64 code[], uniform int pass, uniform int hist[])
+{
+  uniform int start = taskIndex*span;
+  uniform int end = taskIndex == taskCount-1 ? n : start+span;
+  uniform int strip = (end-start)/programCount;
+  uniform int tail = (end-start)%programCount;
+  int i = programCount*taskIndex + programIndex;
+  int g [256];
+
+  cfor (int j = 0; j < 256; j ++)
+  {
+    g[j] = 0;
+  }
+
+  cfor (int k = start+programIndex*strip; k < start+(programIndex+1)*strip; k ++)
+  {
+    unsigned int8 *c = (unsigned int8*) &code[k];
+
+    g[c[pass]] ++;
+  }
+
+  if (programIndex == programCount-1) /* remainder is processed by the last lane */
+  {
+    for (int k = start+programCount*strip; k < start+programCount*strip+tail; k ++)
+    {
+      unsigned int8 *c = (unsigned int8*) &code[k];
+
+      g[c[pass]] ++;
+    }
+  }
+
+  cfor (int j = 0; j < 256; j ++)
+  {
+    hist[j*programCount*taskCount+i] = g[j];
+  }
+}
+
+task void permutation (uniform int span, uniform int n, uniform int64 code[], uniform int pass, uniform int hist[], uniform int64 perm[])
+{
+  uniform int start = taskIndex*span;
+  uniform int end = taskIndex == taskCount-1 ? n : start+span;
+  uniform int strip = (end-start)/programCount;
+  uniform int tail = (end-start)%programCount;
+  int i = programCount*taskIndex + programIndex;
+  int g [256];
+
+  cfor (int j = 0; j < 256; j ++)
+  {
+    g[j] = hist[j*programCount*taskCount+i];
+  }
+
+  cfor (int k = start+programIndex*strip; k < start+(programIndex+1)*strip; k ++)
+  {
+    unsigned int8 *c = (unsigned int8*) &code[k];
+
+    int l = g[c[pass]];
+
+    perm[l] = code[k];
+
+    g[c[pass]] = l+1;
+  }
+
+  if (programIndex == programCount-1) /* remainder is processed by the last lane */
+  {
+    for (int k = start+programCount*strip; k < start+programCount*strip+tail; k ++)
+    {
+      unsigned int8 *c = (unsigned int8*) &code[k];
+
+      int l = g[c[pass]];
+
+      perm[l] = code[k];
+
+      g[c[pass]] = l+1;
+    }
+  }
+}
+
+task void copy (uniform int span, uniform int n, uniform int64 from[], uniform int64 to[])
+{
+  uniform int start = taskIndex*span;
+  uniform int end = taskIndex == taskCount-1 ? n : start+span;
+
+  foreach (i = start ... end)
+  {
+    to[i] = from[i];
+  }
+}
+
+task void pack (uniform int span, uniform int n, uniform unsigned int code[], uniform int64 pair[])
+{
+  uniform int start = taskIndex*span;
+  uniform int end = taskIndex == taskCount-1 ? n : start+span;
+
+  foreach (i = start ... end)
+  {
+    pair[i] = ((int64)i<<32)+code[i];
+  }
+}
+
+task void unpack (uniform int span, uniform int n, uniform int64 pair[], uniform int unsigned code[], uniform int order[])
+{
+  uniform int start = taskIndex*span;
+  uniform int end = taskIndex == taskCount-1 ? n : start+span;
+
+  foreach (i = start ... end)
+  {
+    code[i] = pair[i];
+    order[i] = pair[i]>>32;
+  }
+}
+
+export void sort_ispc (uniform int n, uniform unsigned int code[], uniform int order[], uniform int ntasks)
+{
+  uniform int num = ntasks < 1 ? num_cores () : ntasks;
+  uniform int span = n / num;
+  uniform int hsize = 256*programCount*num;
+  uniform int * uniform hist = uniform new int [hsize+1];
+  uniform int64 * uniform pair = uniform new int64 [n];
+  uniform int64 * uniform temp = uniform new int64 [n];
+  uniform int pass, i;
+
+#if DEBUG
+  if (n < 100)
+  {
+    print ("input: ");
+    for (i = 0; i < n; i ++) print ("%, ", code[i]);
+    print ("\n");
+  }
+#endif
+
+  launch[num] pack (span, n, code, pair);
+  sync;
+
+  for (pass = 0; pass < 4; pass ++)
+  {
+    launch[num] histogram (span, n, pair, pass, hist+1);
+    sync;
+
+    /* TODO: parallelize and vectorize prefix sum */
+    for (hist[0] = 0, i = 1; i < hsize; i ++) hist[i] += hist[i-1];
+
+    launch[num] permutation (span, n, pair, pass, hist, temp);
+    sync;
+
+    launch[num] copy (span, n, temp, pair);
+    sync;
+  }
+
+  launch[num] unpack (span, n, pair, code, order);
+  sync;
+
+#if DEBUG
+  for (i = 0; i < n; i ++)
+  {
+    if (i > 0 && code[i-1] > code[i])
+      print ("ERR at % => % > %; ", i, code[i-1], code[i]);
+  }
+
+  if (n < 100)
+  {
+    print ("output: ");
+    for (i = 0; i < n; i ++) print ("%, ", code[i]);
+    print ("\n");
+    print ("order: ");
+    for (i = 0; i < n; i ++) print ("%, ", order[i]);
+    print ("\n");
+  }
+#endif
+
+  delete hist;
+  delete pair;
+  delete temp;
+}